pkgs/pocket-tts-cpp.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

{
  lib,
  fetchFromGitHub,
  cmake,
  pkg-config,
  stdenv,
  onnxruntime,
  sentencepiece,
  protobuf
}:

let
  dr_libs = fetchFromGitHub {
    owner = "mackron";
    repo = "dr_libs";
    rev = "fa931f3285ced10ace628f7f1ac951e1951e7ea6";
    hash = "sha256-j+xIS6u9bu6+2AcXQ2ChAVHizmEWOxNxj0BA/Gr6qsc=";
  };
in
stdenv.mkDerivation {
  name = "pocket-tts-cpp";
  version = "20260319";
  src = fetchFromGitHub {
    owner = "VolgaGerm";
    repo = "PocketTTS.cpp";
    rev = "5adf81d35b2f26bb84f958cebbcc88847d0be9b4";
    hash = "sha256-4QWZxUmL77BP9Y70n3W17O5Gr3LxahqNKFWljkf2t88=";
  };
  patches = [
    ./pocket-tts-cpp-system-libs.patch
    ./pocket-tts-cpp-install-targets.patch
  ];

  nativeBuildInputs = [
    cmake
    pkg-config
  ];

  buildInputs = [
    onnxruntime
    sentencepiece
    protobuf
  ];

  cmakeFlags = [
    (lib.cmakeBool "BUILD_SHARED_LIB" true)
    (lib.cmakeFeature "FETCHCONTENT_SOURCE_DIR_DR_LIBS" "${dr_libs}")
  ];
}